plugins {
    id 'java'
    id 'com.gradleup.shadow' version '9.4.2'
    id 'xyz.jpenilla.run-paper' version '2.3.1'
}

group = 'eu.milujukockoholky'
version = '3.7.4-beta.1'
description = 'An all-in-one hub management system'

repositories {
    mavenCentral()
    maven { url 'https://oss.sonatype.org/content/groups/public/' }
    maven { url 'https://jitpack.io' }
    maven { url 'https://repo.codemc.org/repository/maven-public' }
    maven { url 'https://repo.extendedclip.com/content/repositories/placeholderapi/' }
    maven { url 'https://libraries.minecraft.net/' }
    maven { url 'https://repo.opencollab.dev/main/' }
    maven { url 'https://repo.aikar.co/content/groups/aikar/' }
    maven { url 'https://repo.papermc.io/repository/maven-public/' }
}

dependencies {
    // Provided dependencies
    compileOnly 'io.papermc.paper:paper-api:26.1.2.build.+'
    compileOnly 'com.mojang:authlib:1.5.25'
    compileOnly 'me.clip:placeholderapi:2.11.6'
    compileOnly 'de.tr7zw:item-nbt-api:2.14.0'
    compileOnly 'com.github.shynixn.headdatabase:hdb-api:1.0'

    // Implementation dependencies (will be included in the jar)
    implementation 'org.bstats:bstats-bukkit-lite:1.7'
    implementation 'javax.inject:javax.inject:1'
    implementation 'javax.annotation:javax.annotation-api:1.2'
    implementation 'co.aikar:acf-paper:0.5.1-SNAPSHOT'
    implementation 'net.kyori:adventure-api:4.21.0'
}

tasks {
    runServer {
        minecraftVersion("26.1.2")
    }

    shadowJar {
        archiveClassifier.set('')

        relocate 'org.bstats', 'eu.milujukockoholky.vexliolobby.libs.metrics'
        relocate 'co.aikar', 'eu.milujukockoholky.vexliolobby.libs.aikar'

        dependencies {
            include(dependency('org.bstats:bstats-bukkit-lite'))
            include(dependency('javax.inject:javax.inject'))
            include(dependency('co.aikar:acf-paper'))
        }
    }

    build {
        dependsOn shadowJar
    }
}

java {
    sourceCompatibility = JavaVersion.VERSION_25
    targetCompatibility = JavaVersion.VERSION_25
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8'
    options.fork = true
    options.forkOptions.executable = "C:/Program Files/Eclipse Adoptium/jdk-25.0.3.9-hotspot/bin/javac.exe"
}

processResources {
    def props = [
            'name': rootProject.name,
            'version': project.version,
            'description': project.description ?: 'An all-in-one hub management system',
            'url': 'https://www.spigotmc.org/resources/118904/'
    ]
    inputs.properties props
    filteringCharset 'UTF-8'
    filesMatching('plugin.yml') {
        expand props
    }
    filesMatching('paper-plugin.yml') {
        expand props
    }
}